`Learning.randomSampling.action_tendsto_any`🔗

Theorem

The minimum distance from sampled actions to any point tends to zero.

theorem

Learning.randomSampling.action_tendsto_any.{u_1, u_2, u_3}
  {𝓐 : Type u_1} {𝓨 : Type u_2} {Ω : Type u_3} {m𝓐 : MeasurableSpace 𝓐}
  {m𝓨 : MeasurableSpace 𝓨} {mΩ : MeasurableSpace Ω}
  {μ : MeasureTheory.Measure 𝓐} [MeasureTheory.IsProbabilityMeasure μ]
  {P : MeasureTheory.Measure Ω} [MeasureTheory.IsProbabilityMeasure P]
  {A : ℕ → Ω → 𝓐} {Y : ℕ → Ω → 𝓨} {f : 𝓐 → 𝓨} {hf : Measurable f}
  [PseudoMetricSpace 𝓐] [SecondCountableTopology 𝓐]
  [OpensMeasurableSpace 𝓐] [MeasureTheory.Measure.IsOpenPosMeasure μ]
  (h : IsAlgEnvSeq A Y (randomSampling μ) (evalEnv f hf) P) (a : 𝓐)
  {ε : ℝ} (hε : 0 < ε) :
  Filter.Tendsto
    (fun i => P {x | ε ≤ Function.min fun j => dist (A (↑j) x) a})
    Filter.atTop (nhds 0)
Learning.randomSampling.action_tendsto_any.{u_1,
    u_2, u_3}
  {𝓐 : Type u_1} {𝓨 : Type u_2}
  {Ω : Type u_3} {m𝓐 : MeasurableSpace 𝓐}
  {m𝓨 : MeasurableSpace 𝓨}
  {mΩ : MeasurableSpace Ω}
  {μ : MeasureTheory.Measure 𝓐}
  [MeasureTheory.IsProbabilityMeasure μ]
  {P : MeasureTheory.Measure Ω}
  [MeasureTheory.IsProbabilityMeasure P]
  {A : ℕ → Ω → 𝓐} {Y : ℕ → Ω → 𝓨}
  {f : 𝓐 → 𝓨} {hf : Measurable f}
  [PseudoMetricSpace 𝓐]
  [SecondCountableTopology 𝓐]
  [OpensMeasurableSpace 𝓐]
  [MeasureTheory.Measure.IsOpenPosMeasure
      μ]
  (h :
    IsAlgEnvSeq A Y (randomSampling μ)
      (evalEnv f hf) P)
  (a : 𝓐) {ε : ℝ} (hε : 0 < ε) :
  Filter.Tendsto
    (fun i =>
      P
        {x |
          ε ≤
            Function.min fun j =>
              dist (A (↑j) x) a})
    Filter.atTop (nhds 0)

Code

theorem action_tendsto_any (h : IsAlgEnvSeq A Y (randomSampling μ) (evalEnv f hf) P) (a : 𝓐)
    {ε : ℝ} (hε : 0 < ε) :
    Tendsto (fun i => P {x | ε ≤ (fun (j : Iic i) ↦ dist (A j.1 x) a).min}) atTop (𝓝 0)

Proof

by
  set randomSampling_alg := randomSampling (𝓨 := 𝓨) μ
  refine tendsto_zero_of_le (g := fun n ↦ P (⋂ i ∈ Iic n, {x | ε ≤ dist (A i x) a})) ?_ ?_
  · have inter_prod (n : ℕ) : P (⋂ j ∈ Iic n, {x | ε ≤ dist (A j x) a}) =
        ∏ j ∈ Iic n, P {x | ε ≤ dist (A j x) a} := by
      refine iIndepSet.meas_biInter ?_ _
      rw [iIndepSet_iff_meas_biInter fun i ↦ ?_]
      · intro s
        have iIndep_actions := randomSampling.iIndep_action h
        rw [iIndepFun_iff_measure_inter_preimage_eq_mul] at iIndep_actions
        have meas_dist : ∀ i ∈ s, MeasurableSet {x | ε ≤ dist x a} := by
          intro i hs
          measurability
        specialize iIndep_actions s meas_dist
        simpa [Set.preimage] using iIndep_actions
      · have hAi := h.measurable_action i
        measurability
    simp_rw [inter_prod]
    have prod_law (n : ℕ) : ∏ j ∈ Iic n, P {x | ε ≤ dist (A j x) a} =
        ∏ j ∈ Iic n, μ {x | ε ≤ dist x a} := by
      refine prod_congr rfl fun j hj ↦ ?_
      have hlaw (n : ℕ) : HasLaw (A n) μ P := randomSampling.hasLaw_action h n
      rw [← (hlaw j).map_eq, P.map_apply]
      · simp
      · exact h.measurable_action j
      · measurability
    simp_rw [prod_law]
    simp only [prod_const, Nat.card_Iic]
    refine tendsto_pow_atTop_nhds_zero_of_lt_one ?_ |> Tendsto.comp <| tendsto_add_atTop_nat 1
    have compl : {x | ε ≤ dist x a} = {x | dist x a < ε}ᶜ := by
      ext a
      simp
    rw [compl, measure_compl (by measurability) (by simp), measure_univ]
    refine ENNReal.sub_lt_self (by simp) (by simp) ?_
    exact (Metric.measure_ball_pos μ a hε).ne'
  · intro n
    refine measure_mono ?_
    simp only [mem_Iic, Set.subset_iInter_iff, Set.ofPred_subset_ofPred]
    intro i hi ω (hω : ε ≤ (fun (j : Iic n) ↦ dist (A j.1 ω) a).min)
    simp_all only [univ_eq_attach, le_inf'_iff, mem_attach, forall_const, Subtype.forall, mem_Iic]

Actions: Source · Open Issue

Meaning last changed in v4.34.0-rc2-1-g439785b (2026-08-23), the 4th recorded change.

Self-contained, with its dependencies inlined and proofs replaced by sorry: download the raw file · open it in the Lean web editor.

Dependency graph

Audit surface: 10 project declarations, 89 external constants

✓ Proved: no sorry anywhere in its closure

This is the tool's own reading of one build's recorded axioms, and it is not robust against an author who wants it to pass. Checking meant to be relied on should go through Comparator, which replays the proof through the kernel from an export against an explicit list of permitted axioms.

Learning.randomSampling.action_tendsto_any🔗

`Learning.randomSampling.action_tendsto_any`🔗